ALTER STREAMING RULE

AlterStreamingRule ::=
  'ALTER' 'STREAMING' 'RULE' '(' readConfiguration? (','? writeConfiguration)? (','? streamChannel)? ')'

readConfiguration ::=
  'READ' '(' workerThread? (','? batchSize)? (','? shardingSize)? (','? rateLimiter)? ')'

writeConfiguration ::=
  'WRITE' '(' workerThread? (','? batchSize)? (','? rateLimiter)? ')'

streamChannel ::=
  'STREAM_CHANNEL' '(' algorithmDefinition ')'

workerThread ::=
  'WORKER_THREAD' '=' int

batchSize ::=
  'BATCH_SIZE' '=' int

shardingSize ::=
  'SHARDING_SIZE' '=' int

rateLimiter ::=
  'RATE_LIMITER' '(' algorithmDefinition ')'

algorithmName ::=
  string

algorithmDefinition ::=
  'TYPE' '(' 'NAME' '=' algorithmName (',' propertiesDefinition)? ')'

propertiesDefinition ::=
  'PROPERTIES' '(' (key '=' value (',' key '=' value)*)? ')'

key ::=
  string

value ::=
  literal

ALTER STREAMING RULE (
  READ(WORKER_THREAD=20, BATCH_SIZE=1000, SHARDING_SIZE=10000000, RATE_LIMITER (TYPE(NAME='QPS', PROPERTIES('qps'='500')))),
  WRITE(WORKER_THREAD=20, BATCH_SIZE=1000, RATE_LIMITER (TYPE(NAME='TPS', PROPERTIES('tps'='2000')))),
  STREAM_CHANNEL (TYPE(NAME='MEMORY', PROPERTIES('block-queue-size'='2000')))
);