复古 护眼 海天 深邃 暗黑 默认

REGISTER MIGRATION SOURCE STORAGE UNIT

描述

REGISTER MIGRATION SOURCE STORAGE UNIT 语法用于为当前连接注册数据迁移源存储单元。

语法

RegisterMigrationSourceStorageUnit ::=
  'REGISTER' 'MIGRATION' 'SOURCE' 'STORAGE' 'UNIT' storageUnitDefinition (',' storageUnitDefinition)*

storageUnitDefinition ::=
  storageUnitName '(' (simpleSource | urlSource) ',' 'USER' '=' user (',' 'PASSWORD' '=' password)? (',' propertiesDefinition)? ')'

storageUnitName ::=
  identifier

simpleSource ::=
  'HOST' '=' hostname ',' 'PORT' '=' port ',' 'DB' '=' dbName

urlSource ::=
  'URL' '=' url

hostname ::=
  string

port ::=
  int

dbName ::=
  string

url ::=
  string

user ::=
  string

password ::=
  string

propertiesDefinition ::=
  'PROPERTIES' '(' (key '=' value (',' key '=' value)*)? ')'

key ::=
  string

value ::=
  literal

特别说明

  • 确认注册的数据迁移源存储单元是可以正常连接的， 否则将不能注册成功；
  • storageUnitName 区分大小写；
  • storageUnitName 在当前连接中需要唯一；
  • storageUnitName 命名只允许使用字母、数字以及 _ ，且必须以字母开头；
  • poolProperty 用于自定义连接池参数，key 必须和连接池参数名一致，value 支持 int 和 String 类型；
  • 当 password 包含特殊字符时，建议使用 string 形式；例如 password@123的 string 形式为 "password@123"；
  • 数据迁移源存储单元支持使用 URL 注册，也支持使用 HOST、PORT 和 DB 注册。

示例

  • 注册数据迁移源存储单元
REGISTER MIGRATION SOURCE STORAGE UNIT ds_0 (
    URL="jdbc:mysql://127.0.0.1:3306/migration_ds_0?serverTimezone=UTC&useSSL=false",
    USER="root",
    PASSWORD="123456"
);
  • 使用主机、端口和数据库名注册数据迁移源存储单元
REGISTER MIGRATION SOURCE STORAGE UNIT ds_0 (
    HOST="127.0.0.1",
    PORT=3306,
    DB="migration_ds_0",
    USER="root",
    PASSWORD="123456"
);
  • 注册数据迁移源存储单元并设置连接池参数
REGISTER MIGRATION SOURCE STORAGE UNIT ds_0 (
    URL="jdbc:mysql://127.0.0.1:3306/migration_ds_0?serverTimezone=UTC&useSSL=false",
    USER="root",
    PASSWORD="123456",
    PROPERTIES("minPoolSize"="1","maxPoolSize"="20","idleTimeout"="60000")
);

保留字

REGISTER、MIGRATION、SOURCE、STORAGE、UNIT、USER、PASSWORD、PROPERTIES、URL、HOST、PORT、DB

相关链接