跳至内容
用户手册
DistSQL
语法
RDL 语法
规则定义
分片
ALTER SHARDING KEY GENERATE STRATEGY

ALTER SHARDING KEY GENERATE STRATEGY

描述

ALTER SHARDING KEY GENERATE STRATEGY 语法用于修改当前所选逻辑库的分片主键生成策略。

语法定义

AlterShardingKeyGenerateStrategy ::=
  'ALTER' 'SHARDING' 'KEY' 'GENERATE' 'STRATEGY' keyGenerateStrategyName '(' keyGenerateStrategyDefinition ')'

keyGenerateStrategyDefinition ::=
  columnKeyGenerateStrategyDefinition
  | sequenceKeyGenerateStrategyDefinition

columnKeyGenerateStrategyDefinition ::=
  'TABLE' '=' tableName ',' 'COLUMN' '=' columnName ',' keyGenerateAlgorithmDefinition

sequenceKeyGenerateStrategyDefinition ::=
  'SEQUENCE' '=' sequenceName ',' keyGenerateAlgorithmDefinition

keyGenerateAlgorithmDefinition ::=
  algorithmDefinition
  | 'GENERATOR' '=' keyGeneratorName

algorithmDefinition ::=
  'TYPE' '(' 'NAME' '=' algorithmType (',' propertiesDefinition)? ')'

propertiesDefinition ::=
  'PROPERTIES' '(' (key '=' value (',' key '=' value)*)? ')'

key ::=
  string

value ::=
  literal

keyGenerateStrategyName ::=
  identifier

tableName ::=
  identifier

columnName ::=
  identifier

sequenceName ::=
  identifier | string

keyGeneratorName ::=
  identifier

algorithmType ::=
  string

补充说明

  • 语法结构与 CREATE SHARDING KEY GENERATE STRATEGY 保持一致；
  • ALTER 会使用新的定义替换已有分片主键生成策略；
  • GENERATOR=... 用于改为引用已有的分片主键生成器；
  • TYPE(NAME=..., PROPERTIES(...)) 用于直接改为新的内联算法定义；
  • algorithmType 为主键生成算法类型，详细信息请参考分布式主键。

示例

  • 修改列维度的分片主键生成策略，并引用已有主键生成器
ALTER SHARDING KEY GENERATE STRATEGY order_id_strategy (
TABLE=t_order,
COLUMN=order_id,
GENERATOR=snowflake_generator
);
  • 修改为序列维度的分片主键生成策略，并使用内联算法
ALTER SHARDING KEY GENERATE STRATEGY order_sequence_strategy (
SEQUENCE="order_seq",
TYPE(NAME="uuid")
);

保留字

ALTER、SHARDING、KEY、GENERATE、STRATEGY、TABLE、COLUMN、SEQUENCE、TYPE、NAME、PROPERTIES、GENERATOR

相关链接

CREATE SHARDING KEY GENERATE STRATEGYCREATE SHARDING KEY GENERATOR