跳至内容
用户手册
DistSQL
语法
RDL 语法
规则定义
读写分离
CREATE READWRITE_SPLITTING RULE

CREATE READWRITE_SPLITTING RULE

描述

。 CREATE READWRITE_SPLITTING RULE 语法用于创建读写分离规则。

语法定义

CreateReadwriteSplittingRule ::=
  'CREATE' 'READWRITE_SPLITTING' 'RULE' ifNotExists? readwriteSplittingDefinition (',' readwriteSplittingDefinition)*

ifNotExists ::=
  'IF' 'NOT' 'EXISTS'

readwriteSplittingDefinition ::=
  ruleName '(' dataSourceDefinition (',' transactionalReadQueryStrategyDefinition)? (',' loadBalancerDefinition)? ')'

dataSourceDefinition ::=
    'WRITE_STORAGE_UNIT' '=' writeStorageUnitName ',' 'READ_STORAGE_UNITS' '(' storageUnitName (',' storageUnitName)* ')' 

transactionalReadQueryStrategyDefinition ::=
    'TRANSACTIONAL_READ_QUERY_STRATEGY' '=' transactionalReadQueryStrategyType

loadBalancerDefinition ::=
    'TYPE' '(' 'NAME' '=' algorithmType (',' propertiesDefinition)? ')'

ruleName ::=
  identifier

writeStorageUnitName ::=
  identifier

storageUnitName ::=
  identifier

transactionalReadQueryStrategyType ::=
  string

algorithmType ::=
  string

propertiesDefinition ::=
  'PROPERTIES' '(' (key '=' value (',' key '=' value)*)? ')'

key ::=
  string

value ::=
  literal

补充说明

  • transactionalReadQueryStrategyType 指定事务内读请求路由策略，请参考YAML 配置；
  • algorithmType 指定负载均衡算法类型，请参考负载均衡算法；
  • 重复的 ruleName 将无法被创建；
  • ifNotExists 子句用于避免出现 Duplicate readwrite_splitting rule 错误。

示例

创建读写分离规则

CREATE READWRITE_SPLITTING RULE ms_group_0 (
    WRITE_STORAGE_UNIT=write_ds,
    READ_STORAGE_UNITS(read_ds_0,read_ds_1),
    TYPE(NAME="random")
);

使用 ifNotExists 子句创建读写分离规则

  • 读写分离规则
CREATE READWRITE_SPLITTING RULE IF NOT EXISTS ms_group_0 (
    WRITE_STORAGE_UNIT=write_ds,
    READ_STORAGE_UNITS(read_ds_0,read_ds_1),
    TYPE(NAME="random")
);

保留字

CREATE、READWRITE_SPLITTING、RULE、WRITE_STORAGE_UNIT、READ_STORAGE_UNITS 、TYPE、NAME、PROPERTIES、TRUE、FALSE

相关链接

ALTER READWRITE_SPLITTING RULE